HB1/HB2 name conventions in X-PLOR

[Alexandre Bonvin]

Hi there again,

Below is a script written to convert X-PLOR HB1/HB2 notation to IUPAC like
notation. This could be run at the structure (psf) generation step (e.g.
call it from generate.inp before writting out the structure file). 
With this script no need to modify the topology files. 
Cheers,
Alexandre

==========================================================================
| Alexandre Bonvin PhD           | Phone: (203) 432-5066                 |
| Mol. Biophys. & Biochemistry   | Fax:   (203) 432-3923                 |
| Yale University                | Email: abonvin at laplace.csb.yale.edu   |
| New Haven CT 06520-8114, USA   |                                       | 
==========================================================================
| http://xplor.csb.yale.edu/group/people/alex_bonvin/alex_bonvin.html    |
==========================================================================

************************ CUT HERE ****************************************
REMARK xplortodiana.inp
REMARK X-PLOR script to convert X-PLOR methylene hydrogen names to the
REMARK the naming convention adopted by DIANA
REMARK Author: Michael Nilges


for $id in id (tag) loop iupa
  {* gly *}  
  vector ident (store1) (byres(id $id) and name ha%)
  if ($select = 2) then 
    vector do (name = " AAA") (store1 and name ha1)
    vector do (name = " HA1") (store1 and name ha2)
    vector do (name = " HA2") (store1 and name AAA)
  end if
  
  {* lys *}  
  vector ident (store1) (byres(id $id) and name he%)
  if ($select = 2) then 
    vector do (name = " HE3") (store1 and name he1)
  end if
  
  {* arg, pro *}
  vector ident (store1) (byres(id $id) and name hd%)
  if ($select = 2) then
    vector do (name = " HD3") (store1 and name hd1)
  end if

  {* gln, glu, met *}
  vector ident (store1) (byres(id $id) and name hg%)
  if ($select = 2) then
    vector do (name = " HG3") (store1 and name hg1)
  end if

  {* ile *}
  vector ident (store1) (byres(id $id) and name hg1%)
  if ($select = 2) then
    vector do (name = "HG13") (store1 and name hg11)
  end if

  {* all betas *}
  vector ident (store1) (byres (id $id) and name hb%)
  if ($select = 2) then
    vector do (name = " HB3") (store1 and name hb1)
  end if


! methyle groups


  vector ident (store1) (byres(id $id) and name hb%)
  if ($select = 3) then 
    vector do (name = " BBB") (store1 and name hb2)
    vector do (name = " HB2") (store1 and name hb1)
    vector do (name = " HB1") (store1 and name BBB)
  end if

  vector ident (store1) (byres(id $id) and name hg1%)
  if ($select = 3) then 
    vector do (name = "GGGG") (store1 and name hg11)
    vector do (name = "HG11") (store1 and name hg12)
    vector do (name = "HG12") (store1 and name GGGG)
  end if
  vector ident (store1) (byres(id $id) and name hg2%)
  if ($select = 3) then 
    vector do (name = "GGGG") (store1 and name hg21)
    vector do (name = "HG21") (store1 and name hg22)
    vector do (name = "HG22") (store1 and name GGGG)
  end if

  vector ident (store1) (byres(id $id) and name hd1%)
  if ($select = 3) then 
    vector do (name = "DDDD") (store1 and name hd11)
    vector do (name = "HD11") (store1 and name hd12)
    vector do (name = "HD12") (store1 and name DDDD)
  end if
  vector ident (store1) (byres(id $id) and name hd2%)
  if ($select = 3) then 
    vector do (name = "DDDD") (store1 and name hd21)
    vector do (name = "HD21") (store1 and name hd22)
    vector do (name = "HD22") (store1 and name DDDD)
  end if

  vector ident (store1) (byres(id $id) and name he%)
  if ($select = 3) then 
    vector do (name = " EEE") (store1 and name he1)
    vector do (name = " HE1") (store1 and name he2)
    vector do (name = " HE2") (store1 and name EEE)
  end if

  vector ident (store1) (byres(id $id) and name hz%)
  if ($select = 3) then 
    vector do (name = " ZZZ") (store1 and name hz1)
    vector do (name = " HZ1") (store1 and name hz2)
    vector do (name = " HZ2") (store1 and name ZZZ)
  end if


! arg nh2's

  vector ident (store1) (byres(id $id) and name hh1%)
  if ($select = 2) then 
    vector do (name = "HHHH") (store1 and name hh11)
    vector do (name = "HH11") (store1 and name hh12)
    vector do (name = "HH12") (store1 and name HHHH)
  end if
  vector ident (store1) (byres(id $id) and name hh2%)
  if ($select = 2) then 
    vector do (name = "HHHH") (store1 and name hh21)
    vector do (name = "HH21") (store1 and name hh22)
    vector do (name = "HH22") (store1 and name HHHH)
  end if


end loop iupa