Hi, X-PLOR users
I am trying to do a bulk solvent correction to a fairly big protein (total
2200 residues in an assymetric unit) and with 160,000 reflections. However
the program (xplor 3.851) crashed with following message
XREFINE> do (fpart=ft(mask)) ( all )
XMAPAL: allocating space for real space object.
Total of 2880000 map elements were selected.
%VEHEAP-ERR: could not satisfy storage request for 2916002 bytes
Subroutine DIE called . Terminating
How should I cope this?
thanks in advance for any hints
Guoguang
p.s: my input file
remarks file xtalrefine/setup_bulksol.inp
remarks
remarks Generates a "flat" bulk solvent model
remarks
remarks Computes solvent mask, do an FFT, optimize k and B, stores in FPART
remarks and writes new reflection file.
remarks
remarks
remarks - run this job
remarks - check that the solvent parameters are reasonable (solvent density
remarks and B-value) and that there is a significant drop in R value
remarks especially at low resolution. If unsatisfactory, try
remarks fixing either the solvent B-factor or solvent density level.
remarks - use setup_bulksol.cv reflection file in all subsequent jobs
remarks - use lower resolution bound in all subsequent jobs
remarks Authors: Jian-Sheng Jiang, William I. Weis and Axel T. Brunger
! Cite the following references when using this protocol:
!
! J.-S. Jiang and A.T. Brunger, Protein hydration
! observed by x-ray diffraction: solvation properties of
! penicillopepsion and neuraminidase crystal structures,
! J. Mol. Biol. 243, 100-115 (1994).
!
!----------------------------------------------------------------------------
{===>} parameter
@/nfs/disk1/guoguang/xplor/parhcsdx.pro
@/nfs/disk1/guoguang/pdc/par.tdp
@/nfs/disk1/guoguang/pdc/par.mg
@par.cit
@/nfs/disk1/guoguang/xplor/param19.sol { Read empirical potential }
end {*Read parameters.*}
{===>} structure @gen.psf end {*Read structure file.*}
{===>} coor @gen.pdb {*Read coordinates.*}
{===>} evaluate ($scatter_library="/usr/programs/xplor3.84/xtallib/scatter.lib")
{ Form factor library. }
{===>} { Space group. Uses International Table conventions. }
{ with supercripts substituted by parenthesis. }
evaluate ($SG="P1" )
{===>} { Unit cell. }
evaluate ($a=69.87)
evaluate ($b=92.01)
evaluate ($c=97.99)
evaluate ($alpha=103.68)
evaluate ($beta=94.54)
evaluate ($gamma=112.32)
{===>}
evaluate ($ref="/nfs/disk2/doreen/cof/p1cof2c.cv") { Input reflection file.
Includes}
{ test set for cross-validation. }
{===>}
evaluate ($out_ref="/nfs/scratch/guoguang/bulksol.cv") { Output reflection
file. }
{===>}
evaluate ($low_res=15.0) {* low resolution limit. *}
evaluate ($high_res=1.86) {* high resolution limit. *}
{===>}
evaluate ($f_cut=1.0) {* F/sigma amplitude cutoff. *}
{===>}
evaluate ($f_low=0.00) {* Absolute amplitude cutoffs. *}
evaluate ($f_high=1000000)
{===>} {* Select atoms to be included in refinement. *}
vector ident (store1) (known)
{===>}
evaluate ($ncs_flag=NONE) { RESTRAIN or STRICT or NONE ! ncs information. }
{===>}
evaluate ($ncs_file="ncs.inp" ) { NCS-restraints/constraints file name.
}
{ Examples are in xtalrefine/ncs_strict.inp }
{ and xtalrefine/ncs_restrain.inp. }
{===>}
evaluate ($k3=0.33) {* Optional: fix set solvent density level by setting}
{* this parameter to a positive value. }
{===>}
evaluate ($b3=50.) {* Optional: fix set solvent b-factor by setting }
{* this parameter to a positive value. }
!----------------------------------------------------------------------------
xrefine
@/usr/programs/xplor3.84/xtallib/spacegroup.lib { Read symmetry
library. }
a=$a b=$b c=$c alpha=$alpha beta=$beta gamma=$gamma { Define unit cell. }
@$scatter_library { Read form factor library }
nreflections= 160000
reflection @$ref end
resolution_limits= $low_res $high_res
do (fobs=0) (amplitude(fobs) <= $f_cut * sigma)
fwindow $f_low $f_high
method=FFT
fft
memory=3000000
end
selection=( store1 )
end
if ($ncs_flag=STRICT) then
@@$ncs_file
elseif ($ncs_flag=RESTRAIN) then
@@$ncs_file
flags include ncs end
end if
xrefin
update {*Update Fcalcs and print current rfactor.*}
print rfactor
end
xrefine
{* compute a solvent mask and store it in mask *}
declare name=mask domain=real end
mask
mode=vdw { use vdw radii }
solrad=0.25 { a probe radius adds to vdw radii }
shrink=0.25 { the shrink radius }
nshell=1 { the number of shells }
to=mask { output to the mask map }
end
{* Fourier transformation of the solvent mask and store it in fpart*}
do (fpart=ft(mask)) ( all )
{* solvent parameters refinement via by the multiscale routine *}
multiscale
bfmin=0. bfmax=200.
set1=fobs k1=-1 b1=0
set2=fcalc k2=1.0 b2=0
set3=fpart k3=$k3 b3=$b3
selection=( $high_res <= d <= $low_res
and $f_low <= amplitude(fobs) <= $f_high
and test=0 )
resk=5.0 { resolution boundary for two FFKs }
update=false
bmin=10.
bmax=300.
?
end
{* compute refined solvent structure factors in fbulk *}
do (fpart=$k3*exp(-$b3*s()*s()/4.0)*fpart) ( all )
display bulk solvent model parameters: density level = $k3 e/A^3, B-factor=
$b3 A^2
remarks bulk solvent model parameters: density level = $k3 e/A^3, B-factor=
$b3 A^2
print rfactor
do (fcalc=complex(0,0)) ( all )
{*Write a new reflection file including the solvent FPART.*}
write reflection
output=$out_ref sele=( all )
end
end
stop
